#include "./../system/Sound.txt"
#include "./MenuResult.txt"

@Initialize
{	
	PlaySound("se_Pause",120);
	SetAutoDeleteObject(true);
	TBackground();
	TMenu();
}

@MainLoop
{
	yield;
}

@Finalize
{
}


task TBackground
{
	task TVertex(var index, var left, var top, var right, var bottom, var time)
		{
		ObjPrim_SetVertexPosition(obj, index + 0, left, top, 0);
		ObjPrim_SetVertexPosition(obj, index + 1, left, bottom, 0);
		ObjPrim_SetVertexPosition(obj, index + 2, right, top, 0);
		ObjPrim_SetVertexPosition(obj, index + 3, right, top, 0);
		ObjPrim_SetVertexPosition(obj, index + 4, left, bottom, 0);
		ObjPrim_SetVertexPosition(obj, index + 5, right, bottom, 0);

		ObjPrim_SetVertexUVT(obj, index + 0, left, top);
		ObjPrim_SetVertexUVT(obj, index + 1, left, bottom);
		ObjPrim_SetVertexUVT(obj, index + 2, right, top);
		ObjPrim_SetVertexUVT(obj, index + 3, right, top);
		ObjPrim_SetVertexUVT(obj, index + 4, left, bottom);
		ObjPrim_SetVertexUVT(obj, index + 5, right, bottom);

		loop(time){yield;}

		let alpha = 255;	
		while(alpha >= (absolute(200-left)+top)*75/(848)+125)
			{
			ObjPrim_SetVertexAlpha(obj, index + 0, alpha);
			ObjPrim_SetVertexAlpha(obj, index + 1, alpha/2);
			ObjPrim_SetVertexAlpha(obj, index + 2, alpha/2);
			ObjPrim_SetVertexAlpha(obj, index + 3, alpha/2);
			ObjPrim_SetVertexAlpha(obj, index + 4, alpha/2);
			ObjPrim_SetVertexAlpha(obj, index + 5, alpha);
			alpha -= 255 / (frame-time/2);
			yield;
			}
		}

	let frame = 20;
	let countH = 20;
	let countV = 30; 
	let width = 720 / countH;
	let height = 480 / countV;
	let target = GetTransitionRenderTargetName();
	let obj = ObjPrim_Create(OBJ_PRIMITIVE_2D);
	ObjPrim_SetPrimitiveType(obj, PRIMITIVE_TRIANGLELIST);
	ObjPrim_SetVertexCount(obj, countH * countV * 6);
	Obj_SetRenderPriorityI(obj, 0);
	ObjPrim_SetTexture(obj, target);

	ascent(ix in 0.. countH)
	{
		ascent(iy in 0.. countV)
		{
			let time = (absolute(countV/2-iy)+countH-absolute(countH/2-ix))*frame/(countH+countV);
			let index = (ix + iy * countH) * 6;
			let left = ix * width;
			let right = left + width;
			let top = iy * height;
			let bottom = top + height;
			TVertex(index, left, top, right, bottom, time);
		}
	}

}

task TMenu
{
	let selectIndex = 0;
	task TMenuItem(let index, let mx, let my, let text)
		{
		function CreateTextObject(let mx, let my, let text)
			{
			let obj = ObjText_Create();
			ObjText_SetText(obj, text);
			ObjText_SetFontBold(obj, true);
			ObjText_SetFontType(obj,"Century Gothic");
			ObjText_SetFontSize(obj, 24);
			ObjText_SetSidePitch(obj,1);
			ObjText_SetFontBold(obj, true);
			ObjText_SetFontColorTop(obj, 128, 255, 255);
			ObjText_SetFontColorBottom(obj, 64, 196, 196);
			ObjText_SetFontBorderType(obj, BORDER_FULL);
			ObjText_SetFontBorderColor(obj,64,64,64);
			ObjText_SetFontBorderWidth(obj, 2);
			Obj_SetRenderPriorityI(obj, 10);
			ObjRender_SetX(obj, mx);
			ObjRender_SetY(obj, my);
			return obj;
			}

		let objText = CreateTextObject(mx, my, text);
		let objSelect = CreateTextObject(mx, my, text);
		ObjRender_SetBlendType(objSelect, BLEND_ADD_RGB);
		loop
			{
			Obj_SetVisible(objSelect, index == selectIndex);
			yield;
			}
		}

	let mx = 128;
	let my = 32;
	let texts = ["Resume", "Try Again", "Return to Title", "Close Game"];
	let listResult = [RESULT_CONTINUE, RESULT_RESTART,RESULT_TITLE, RESULT_CLOSE];
	var countMenu = length(texts);
	ascent(var iText in 0 .. countMenu)
		{
		TMenuItem(iText, mx, my, texts[iText]);
		my += 32;
		}

	while(GetVirtualKeyState(VK_PAUSE) != KEY_FREE){yield;}

	let frameKeyHold = 0;
	loop
		{
		if(GetKeyState(KEY_R) == KEY_PUSH)
			{
			selectIndex = 1;
			SetScriptResult(listResult[selectIndex]);
			CloseScript(GetOwnScriptID());
			loop(20){yield;}
			PlaySound("se_Confirm",120);
			return;
			}
		if(GetVirtualKeyState(VK_OK) == KEY_PULL)
			{	
			PlaySound("se_Confirm",120);
			SetScriptResult(listResult[selectIndex]);
			loop(20){yield;}
			CloseScript(GetOwnScriptID());
			return;
			}

		if(GetVirtualKeyState(VK_CANCEL) == KEY_PULL || GetVirtualKeyState(VK_PAUSE) == KEY_PULL)
			{
			SetScriptResult(RESULT_CONTINUE);
			CloseScript(GetOwnScriptID());
			PlaySound("se_Confirm",120);
			return;
			}

		if(GetVirtualKeyState(VK_UP) == KEY_PUSH)
			{
			PlaySound("se_Select",120);
			selectIndex--;
			}
		else if(GetVirtualKeyState(VK_DOWN) == KEY_PUSH)
			{
			PlaySound("se_Select",120);
			selectIndex++;
			}
		else if(GetVirtualKeyState(VK_UP) == KEY_HOLD)
			{
			frameKeyHold++;
			if(frameKeyHold == 30 || (frameKeyHold > 30 && (frameKeyHold % 10 == 0)))
				{
				PlaySound("se_Select",120);
				selectIndex--;
				}
			}
		else if(GetVirtualKeyState(VK_DOWN) == KEY_HOLD)
			{
			frameKeyHold++;
			if(frameKeyHold == 30 || (frameKeyHold > 30 && (frameKeyHold % 10 == 0)))
				{
				PlaySound("se_Select",120);
				selectIndex++;
				}
			}
		else
			{
			frameKeyHold = 0;
			}

		if(selectIndex < 0) 
			{
			selectIndex = countMenu - 1;
			}
		else
			{
			selectIndex %= countMenu;
			}

		yield;
		}
}



