#TouhouDanmakufu
#Title[Spell Card 4]
#Text[Easy Mode.]
#Player[FREE]
#ScriptVersion[2]

script_enemy_main{
let CSD = GetCurrentScriptDirectory;
let niceshot = CSD~"\supershot\supershot.txt";
let death = CSD~"BossDeath.wav";
let time01 = CSD~"timeout01.wav";
let time02 = CSD~"timeout02.wav";
let frame = 0;
let spellbg = CSD~"spellbg.png";
let spellbg2 = CSD~"spellbg2.png";
let circle = CSD~"Circle.png";
let SE1 = CSD~"Shot1.WAV";
let SE2 = CSD~"Shot2.WAV";
let SE4 = CSD~"Shot4.WAV";
let booksheet = CSD~"servant.png";
#include_function ".\AnimationLib.dnh"
#include_function ".\FunctionLib.dnh"


 @Initialize{
                LoadUserShotData(niceshot);
                LoadGraphic(circle);
                LoadGraphic(booksheet);
				LoadGraphic(spellbg2);
                LoadGraphic(spellbg);
		SetLife(1000);
		SetTimer(60);
                SetScore(100000);
		SetInvincibility(100);
		SetMovePosition03(GetCenterX, GetCenterY-120, 10, 4);
                SetDamageRate(10,5);
                SetEffectForZeroLife(70,200,1);
				SetText("Fire & Earth Sign"\""Meteorite Wheel"\");
                mainTask;
                Timer;

    CreateAnimation("book", "intro", 4);
    SetAnimationFrame("book", "intro", 0, booksheet, 12, 0, 2, 31, 30);
    SetAnimationFrame("book", "intro", 1, booksheet, 12, 31, 2, 62, 30);
    SetAnimationFrame("book", "intro", 2, booksheet, 12, 62, 2, 93, 30);
    SetAnimationFrame("book", "intro", 3, booksheet, 12, 93, 2, 124, 30);

    Animate("book","intro",false);

  }


  @MainLoop{
  yield;
  SetCollisionA(GetX,GetY,10);
  SetCollisionB(GetX,GetY,15);
  if(frame<900){frame++;}
  if(frame==800){SetDamageRate(50,50);}
 }

 let circlespin = 0;
 let wave = 0;
 let float = 0;

 @DrawLoop{
  SetTexture(circle);
  SetGraphicRect(64,64,192,192);
  SetGraphicScale(1+sin(wave)*0.5,1+sin(wave)*0.5);
  SetGraphicAngle(0,0,circlespin);
  SetAlpha(150);
  DrawGraphic(GetX,GetY);
  circlespin+=5;
  wave+=2;

  SetTexture(booksheet);
  SetGraphicScale(1,1);
  SetAlpha(255);
  SetGraphicAngle(0,0,0);
  DrawAnimatedSprite("book", GetX, GetY+sin(float)*4);
  float += (1/((|GetSpeedX|)+1))*3;

 }

 @Finalize{
 }

 let bgalpha=0;
 let bgalpha2=0;
 let bgscroll=0;
 
 @BackGround{
    if(bgalpha<100){bgalpha+=2;}
  if(bgalpha2<70){bgalpha2+=2;}
  
  SetTexture(spellbg);
  SetGraphicRect(0,0,256,256);
  SetGraphicScale(2,2);
  SetAlpha(bgalpha);
  DrawGraphic(GetCenterX,GetCenterY);
  
  SetTexture(spellbg2);
  SetGraphicRect(0+bgscroll,0+bgscroll,256+bgscroll,256+bgscroll);
  SetGraphicScale(2,2);
  SetAlpha(bgalpha2);
  DrawGraphic(GetCenterX,GetCenterY);
  
  bgscroll+=2;
 }

     task mainTask{
     wait(100);
     let addangle=0;
	 PlaySE(SE2);
	 ascent(i in 0..2){
     ascent(m in 0..5){
	 circlebullet(m*360/5,0,-2+i*4,195,60,-100-i*100,100+i*100);
	 }}
	 
     }
	 
	 task circlebullet(angle,radius,speed,graphic,delay,minradius,maxradius){
	 let ID = Obj_Create(OBJ_SHOT);
	 let frame = 0;
	 let frame2 = 0;
	 let addangle = 0;
	 let radiuschange = 1;
	 
	 Obj_SetPosition(ID,GetX+cos(angle)*radius,GetY+sin(angle)*radius);
	 ObjShot_SetGraphic(ID,graphic);
	 ObjShot_SetDelay(ID,delay);
	 Obj_SetAutoDelete(ID,false);
	 ObjShot_SetBombResist(ID,true);
	 
	 
	 while(!Obj_BeDeleted(ID)){

	 angle+=speed;
	
	 Obj_SetPosition(ID,GetX+cos(angle)*radius,GetY+sin(angle)*radius);
	 
	 if(speed<0){
	 Obj_SetAngle(ID,angle-90);
	 }
	 
	 if(speed>=0){
	 Obj_SetAngle(ID,angle+90);
	 }
	 
	 if(radius==maxradius){radiuschange=-1;}
	 
	 if(radius==minradius){radiuschange=1;}
	
	 if(frame==12 && speed<0){
     PlaySE(SE4);
	 CreateShot01(Obj_GetX(ID),Obj_GetY(ID),2,Obj_GetAngle(ID)+addangle,237,20);
     
	 addangle+=7.5;
	 frame=0;}
	 
	 if(frame==12 && speed>=0){
     PlaySE(SE4);
	 CreateShot01(Obj_GetX(ID),Obj_GetY(ID),2,Obj_GetAngle(ID)-addangle,237,20);
     
	 addangle+=7.5;
	 frame=0;}
	 
	 if(frame2==260){
	 PlaySE(SE1);
	 ascent(i in -4..4){
	 CreateShot01(Obj_GetX(ID),Obj_GetY(ID),1,Obj_GetAngle(ID)-180+i*5,148,0);
	 }
	 frame2=0;
	 }
	 
	 radius+=radiuschange;
	 frame++;
	 frame2++;
	 yield;
	 
	 }
	 }


     task Timer{
     loop{
	if (GetTimer > 5 && GetTimer <= 11){PlaySE(time01);}
	if (GetTimer >= 1 && GetTimer <= 5){PlaySE(time02);}
	wait(60);
	}
        }
     
}
